This enables generating module option documentation. This commit was genereated by running the following script inside the repo root dir: def add_default_text(file) src = File.read(file) src2 = src.gsub(/( = mkOption\s+\{[^{]*?)(\n\s+default = )(.*?);$(.*?\})/m) do |str| pre, defaultVar, default, post = Regexp.last_match.captures replacement = if !post.include?('defaultText =') if default =~ /\bpkgs\b/ defaultText = default.lines.length == 1 ? default : "(See source)" "#{pre}#{defaultVar}#{default};#{defaultVar.sub('default', 'defaultText')}#{defaultText.inspect};#{post}" end end replacement or str end File.write(file, src2) if src2 != src end Dir["modules/**/*.nix"].each do |f| next if File.basename(f) == "nix-bitcoin.nix" add_default_text f end
122 lines
3.7 KiB
Nix
122 lines
3.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
options.services.lightning-loop = {
|
|
enable = mkEnableOption "lightning-loop";
|
|
rpcAddress = mkOption {
|
|
type = types.str;
|
|
default = "localhost";
|
|
description = "Address to listen for gRPC connections.";
|
|
};
|
|
rpcPort = mkOption {
|
|
type = types.port;
|
|
default = 11010;
|
|
description = "Port to listen for gRPC connections.";
|
|
};
|
|
restAddress = mkOption {
|
|
type = types.str;
|
|
default = cfg.rpcAddress;
|
|
description = "Address to listen for REST connections.";
|
|
};
|
|
restPort = mkOption {
|
|
type = types.port;
|
|
default = 8081;
|
|
description = "Port to listen for REST connections.";
|
|
};
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = config.nix-bitcoin.pkgs.lightning-loop;
|
|
defaultText = "config.nix-bitcoin.pkgs.lightning-loop";
|
|
description = "The package providing lightning-loop binaries.";
|
|
};
|
|
dataDir = mkOption {
|
|
type = types.path;
|
|
default = "/var/lib/lightning-loop";
|
|
description = "The data directory for lightning-loop.";
|
|
};
|
|
proxy = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = if cfg.tor.proxy then config.nix-bitcoin.torClientAddressWithPort else null;
|
|
description = "host:port of SOCKS5 proxy for connnecting to the loop server.";
|
|
};
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
example = ''
|
|
debuglevel=trace
|
|
'';
|
|
description = "Extra lines appended to the configuration file.";
|
|
};
|
|
cli = mkOption {
|
|
default = pkgs.writeScriptBin "loop" ''
|
|
${cfg.package}/bin/loop \
|
|
--rpcserver ${nbLib.addressWithPort cfg.rpcAddress cfg.rpcPort} \
|
|
--macaroonpath '${cfg.dataDir}/${network}/loop.macaroon' \
|
|
--tlscertpath '${secretsDir}/loop-cert' "$@"
|
|
'';
|
|
defaultText = "(See source)";
|
|
description = "Binary to connect with the lightning-loop instance.";
|
|
};
|
|
tor = nbLib.tor;
|
|
};
|
|
|
|
cfg = config.services.lightning-loop;
|
|
nbLib = config.nix-bitcoin.lib;
|
|
secretsDir = config.nix-bitcoin.secretsDir;
|
|
|
|
lnd = config.services.lnd;
|
|
|
|
network = config.services.bitcoind.network;
|
|
configFile = builtins.toFile "loop.conf" ''
|
|
datadir=${cfg.dataDir}
|
|
network=${network}
|
|
rpclisten=${cfg.rpcAddress}:${toString cfg.rpcPort}
|
|
restlisten=${cfg.restAddress}:${toString cfg.restPort}
|
|
logdir=${cfg.dataDir}/logs
|
|
tlscertpath=${secretsDir}/loop-cert
|
|
tlskeypath=${secretsDir}/loop-key
|
|
|
|
lnd.host=${nbLib.addressWithPort lnd.rpcAddress lnd.rpcPort}
|
|
lnd.macaroonpath=${lnd.networkDir}/admin.macaroon
|
|
lnd.tlspath=${lnd.certPath}
|
|
|
|
${optionalString (cfg.proxy != null) "server.proxy=${cfg.proxy}"}
|
|
|
|
${cfg.extraConfig}
|
|
'';
|
|
in {
|
|
inherit options;
|
|
|
|
config = mkIf cfg.enable {
|
|
services.lnd.enable = true;
|
|
|
|
environment.systemPackages = [ cfg.package (hiPrio cfg.cli) ];
|
|
|
|
systemd.tmpfiles.rules = [
|
|
"d '${cfg.dataDir}' 0770 ${lnd.user} ${lnd.group} - -"
|
|
];
|
|
|
|
systemd.services.lightning-loop = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
requires = [ "lnd.service" ];
|
|
after = [ "lnd.service" ];
|
|
serviceConfig = nbLib.defaultHardening // {
|
|
ExecStart = "${cfg.package}/bin/loopd --configfile=${configFile}";
|
|
User = lnd.user;
|
|
Restart = "on-failure";
|
|
RestartSec = "10s";
|
|
ReadWritePaths = cfg.dataDir;
|
|
} // nbLib.allowedIPAddresses cfg.tor.enforce;
|
|
};
|
|
|
|
nix-bitcoin.secrets = {
|
|
loop-key.user = lnd.user;
|
|
loop-cert.user = lnd.user;
|
|
};
|
|
nix-bitcoin.generateSecretsCmds.lightning-loop = ''
|
|
makeCert loop '${optionalString (cfg.rpcAddress != "localhost") "IP:${cfg.rpcAddress}"}'
|
|
'';
|
|
};
|
|
}
|