7a97304f13
Systemd's `Description` option is a misnomer (as confessed by `man systemd.unit`): Its value is used by user-facing tools in place of the unit file name, so this option could have been more aptly named `label` or `name`. `Description` should only be set if the unit file name is not sufficient for naming a unit. This is not the case for our services, except for `systemd.services.nb-netns-bridge` whose description has been kept. As an example how this affects users, weird journal lines like ``` nb-test systemd[1]: Starting Run clightningd... ``` are now replaced by ``` nb-test systemd[1]: Starting clightning.service... ```
86 lines
2.6 KiB
Nix
86 lines
2.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.spark-wallet;
|
|
nbLib = config.nix-bitcoin.lib;
|
|
|
|
# Use wasabi rate provider because the default (bitstamp) doesn't accept
|
|
# connections through Tor
|
|
torRateProvider = "--rate-provider wasabi --proxy socks5h://${config.services.tor.client.socksListenAddress}";
|
|
startScript = ''
|
|
${optionalString (cfg.getPublicAddressCmd != "") ''
|
|
publicURL="--public-url http://$(${cfg.getPublicAddressCmd})"
|
|
''}
|
|
exec ${config.nix-bitcoin.pkgs.spark-wallet}/bin/spark-wallet \
|
|
--ln-path '${config.services.clightning.networkDir}' \
|
|
--host ${cfg.address} --port ${toString cfg.port} \
|
|
--config '${config.nix-bitcoin.secretsDir}/spark-wallet-login' \
|
|
${optionalString cfg.enforceTor torRateProvider} \
|
|
$publicURL \
|
|
--pairing-qr --print-key ${cfg.extraArgs}
|
|
'';
|
|
in {
|
|
options.services.spark-wallet = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
If enabled, the spark-wallet service will be installed.
|
|
'';
|
|
};
|
|
address = mkOption {
|
|
type = types.str;
|
|
default = "localhost";
|
|
description = "http(s) server address.";
|
|
};
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 9737;
|
|
description = "http(s) server port.";
|
|
};
|
|
extraArgs = mkOption {
|
|
type = types.separatedString " ";
|
|
default = "";
|
|
description = "Extra command line arguments passed to spark-wallet.";
|
|
};
|
|
getPublicAddressCmd = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
description = ''
|
|
Bash expression which outputs the public service address.
|
|
If set, spark-wallet prints a QR code to the systemd journal which
|
|
encodes an URL for accessing the web interface.
|
|
'';
|
|
};
|
|
inherit (nbLib) enforceTor;
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
services.clightning.enable = true;
|
|
|
|
users.users.spark-wallet = {
|
|
group = "spark-wallet";
|
|
extraGroups = [ "clightning" ];
|
|
};
|
|
users.groups.spark-wallet = {};
|
|
|
|
systemd.services.spark-wallet = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
requires = [ "clightning.service" ];
|
|
after = [ "clightning.service" ];
|
|
script = startScript;
|
|
serviceConfig = nbLib.defaultHardening // {
|
|
User = "spark-wallet";
|
|
Restart = "on-failure";
|
|
RestartSec = "10s";
|
|
} // (if cfg.enforceTor
|
|
then nbLib.allowTor
|
|
else nbLib.allowAnyIP)
|
|
// nbLib.nodejs;
|
|
};
|
|
nix-bitcoin.secrets.spark-wallet-login.user = "spark-wallet";
|
|
};
|
|
}
|