3681f118f7
This enables generating module option documentation.
This commit was genereated by running the following script inside the
repo root dir:
def add_default_text(file)
src = File.read(file)
src2 = src.gsub(/( = mkOption\s+\{[^{]*?)(\n\s+default = )(.*?);$(.*?\})/m) do |str|
pre, defaultVar, default, post = Regexp.last_match.captures
replacement =
if !post.include?('defaultText =')
if default =~ /\bpkgs\b/
defaultText = default.lines.length == 1 ? default : "(See source)"
"#{pre}#{defaultVar}#{default};#{defaultVar.sub('default', 'defaultText')}#{defaultText.inspect};#{post}"
end
end
replacement or str
end
File.write(file, src2) if src2 != src
end
Dir["modules/**/*.nix"].each do |f|
next if File.basename(f) == "nix-bitcoin.nix"
add_default_text f
end
55 lines
1.6 KiB
Nix
55 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
options.services.lnd.restOnionService = {
|
|
enable = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Create an onion service for the lnd REST service.
|
|
Add a `lndconnect-rest-onion` binary (https://github.com/LN-Zap/lndconnect) to the system environment.
|
|
This binary generates QR codes or URIs for connecting applications to lnd via the REST onion service.
|
|
'';
|
|
};
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = config.nix-bitcoin.pkgs.lndconnect;
|
|
defaultText = "config.nix-bitcoin.pkgs.lndconnect";
|
|
description = "The package providing lndconnect binaries.";
|
|
};
|
|
};
|
|
|
|
cfg = config.services.lnd.restOnionService;
|
|
nbLib = config.nix-bitcoin.lib;
|
|
runAsUser = config.nix-bitcoin.runAsUserCmd;
|
|
|
|
lnd = config.services.lnd;
|
|
|
|
bin = pkgs.writeScriptBin "lndconnect-rest-onion" ''
|
|
#!/usr/bin/env -S ${runAsUser} ${lnd.user} ${pkgs.bash}/bin/bash
|
|
|
|
exec ${cfg.package}/bin/lndconnect \
|
|
--host=$(cat ${config.nix-bitcoin.onionAddresses.dataDir}/lnd/lnd-rest) \
|
|
--port=${toString lnd.restPort} \
|
|
--lnddir=${lnd.dataDir} \
|
|
--tlscertpath=${lnd.certPath} "$@"
|
|
'';
|
|
in {
|
|
inherit options;
|
|
|
|
config = mkIf cfg.enable {
|
|
services.tor = {
|
|
enable = true;
|
|
relay.onionServices.lnd-rest = nbLib.mkOnionService {
|
|
target.addr = nbLib.address lnd.restAddress;
|
|
target.port = lnd.restPort;
|
|
port = lnd.restPort;
|
|
};
|
|
};
|
|
nix-bitcoin.onionAddresses.access.lnd = [ "lnd-rest" ];
|
|
|
|
environment.systemPackages = [ bin ];
|
|
};
|
|
}
|